#
# generrcode.awk
#
# qseawk -f generrcode.awk awk.h
#

BEGIN { 
	collect=0; 
	tab3="\t\t";
	tab4="\t\t\t";
}

/^[[:space:]]*enum[[:space:]]+qse_awk_errnum_t[[:space:]]*$/ { 
	collect=1; 
	print tab3 "// generated by generrcode.awk";
	print tab3 "enum ErrorNumber";
	print tab3 "{";
}

collect && /^[[:space:]]*};[[:space:]]*$/ { 
	print tab3 "};";
	print tab3 "// end of enum ErrorNumber";
	print "";
	collect=0; 
}

collect && /^[[:space:]]*QSE_AWK_E[[:alnum:]]+/ { 
	split ($1, flds, ",");
	name=flds[1];

	print tab4 "ERR_" substr (name,10,length(name)-9) " = " name ",";
}

