hawk/tools/gen-big5-tabs.hawk

# Generate the dense Big5 lookup arrays used by lib/big5.c
#
# Usage:
#   hawk -f tools/gen-big5-tabs.hawk -- tools/BIG5.TXT
#   hawk -f tools/gen-big5-tabs.hawk -- --forward tools/BIG5.TXT
#   hawk -f tools/gen-big5-tabs.hawk -- --reverse tools/BIG5.TXT
#

BEGIN {
	MODE = "all";
	bad = 0;

	init_forward_pages();
	init_reverse_pages();
	parse_args();
}

/^[ \t]*0x[0-9A-Fa-f]+[ \t]+0x[0-9A-Fa-f]+/ {
	@local big5, uc;

	big5 = parse_hex($1);
	uc = parse_hex($2);

	if (big5 < 0 || uc < 0) next;

	if (big5 >= 0xA140)
		add_forward_mapping(big5, uc);

	add_reverse_mapping(big5, uc);
}

END {
	@local i, first;

	if (bad) exit 1;

	printf("/* generated by tools/gen-big5-tabs.hawk from %s */\n\n", input_name());

	first = 1;

	if (MODE == "all" || MODE == "forward")
	{
		for (i = 1; i <= fwd_page_count; i++)
		{
			if (!first) printf("\n");
			dump_forward_page(i);
			first = 0;
		}
	}

	if (MODE == "all" || MODE == "reverse")
	{
		for (i = 1; i <= rev_page_count; i++)
		{
			if (!first) printf("\n");
			dump_reverse_page(i);
			first = 0;
		}
	}
}

function parse_args()
{
	@local i, a;

	for (i = 1; i < ARGC; i++)
	{
		a = ARGV[i];
		if (a == "" || substr(a, 1, 2) != "--") continue;

		if (a == "--all")
			MODE = "all";
		else if (a == "--forward")
			MODE = "forward";
		else if (a == "--reverse")
			MODE = "reverse";
		else
		{
			printf("unknown option %s\n", a) > "/dev/stderr";
			bad = 1;
		}

		ARGV[i] = "";
	}
}

function input_name()
{
	@local i, sep, out;

	sep = "";
	out = "";

	for (i = 1; i < ARGC; i++)
	{
		if (ARGV[i] == "") continue;
		out = out sep ARGV[i];
		sep = ", ";
	}

	return (out != "")? out: "<stdin>";
}

function hex_digit(ch)
{
	if (ch >= "0" && ch <= "9") return ch + 0;
	if (ch >= "A" && ch <= "F") return 10 + index("ABCDEF", ch) - 1;
	if (ch >= "a" && ch <= "f") return 10 + index("abcdef", ch) - 1;
	return -1;
}

function parse_hex(s)
{
	@local i, n, d;
	n = 0;

	if (substr(s, 1, 2) == "0x" || substr(s, 1, 2) == "0X")
		s = substr(s, 3);

	for (i = 1; i <= length(s); i++)
	{
		d = hex_digit(substr(s, i, 1));
		if (d < 0) return -1;
		n = n * 16 + d;
	}

	return n;
}

function init_forward_pages()
{
	fwd_page_count = 2;

	fwd_page_no[1] = 0;
	fwd_name[1] = "big5_to_uc_0";
	fwd_from[1] = 0xA140;
	fwd_to[1] = 0xC7FC;

	fwd_page_no[2] = 1;
	fwd_name[2] = "big5_to_uc_1";
	fwd_from[2] = 0xC940;
	fwd_to[2] = 0xF9DC;

	for (i = 1; i <= fwd_page_count; i++)
		fwd_len[i] = fwd_to[i] - fwd_from[i] + 1;
}

function init_reverse_pages()
{
	rev_page_count = 11;

	rev_page_no[1] = 0; rev_name[1] = "uc_to_big5_0"; rev_from[1] = 0x00A2; rev_to[1] = 0x00F7;
	rev_page_no[2] = 1; rev_name[2] = "uc_to_big5_1"; rev_from[2] = 0x02C7; rev_to[2] = 0x0451;
	rev_page_no[3] = 2; rev_name[3] = "uc_to_big5_2"; rev_from[3] = 0x2013; rev_to[3] = 0x22BF;
	rev_page_no[4] = 3; rev_name[4] = "uc_to_big5_3"; rev_from[4] = 0x2460; rev_to[4] = 0x2642;
	rev_page_no[5] = 4; rev_name[5] = "uc_to_big5_4"; rev_from[5] = 0x3000; rev_to[5] = 0x3129;
	rev_page_no[6] = 5; rev_name[6] = "uc_to_big5_5"; rev_from[6] = 0x32A3; rev_to[6] = 0x32A3;
	rev_page_no[7] = 6; rev_name[7] = "uc_to_big5_6"; rev_from[7] = 0x338E; rev_to[7] = 0x33D5;
	rev_page_no[8] = 7; rev_name[8] = "uc_to_big5_7"; rev_from[8] = 0x4E00; rev_to[8] = 0x9483;
	rev_page_no[9] = 8; rev_name[9] = "uc_to_big5_8"; rev_from[9] = 0x9577; rev_to[9] = 0x9FA4;
	rev_page_no[10] = 9; rev_name[10] = "uc_to_big5_9"; rev_from[10] = 0xFA0C; rev_to[10] = 0xFA0D;
	rev_page_no[11] = 10; rev_name[11] = "uc_to_big5_10"; rev_from[11] = 0xFE30; rev_to[11] = 0xFFFD;

	for (i = 1; i <= rev_page_count; i++)
		rev_len[i] = rev_to[i] - rev_from[i] + 1;
}

function add_forward_mapping(big5, uc)
{
	@local i, idx, old;

	for (i = 1; i <= fwd_page_count; i++)
	{
		if (big5 < fwd_from[i] || big5 > fwd_to[i]) continue;

		idx = big5 - fwd_from[i];
		old = fwd_data[i][idx] + 0;
		if (old != 0 && old != uc)
		{
			printf("duplicate forward mapping for 0x%04x: 0x%04x vs 0x%04x\n", big5, old, uc) > "/dev/stderr";
			bad = 1;
			return;
		}

		fwd_data[i][idx] = uc;
		return;
	}
}

function add_reverse_mapping(big5, uc)
{
	@local i, idx, old;

	for (i = 1; i <= rev_page_count; i++)
	{
		if (uc < rev_from[i] || uc > rev_to[i]) continue;

		idx = uc - rev_from[i];
		old = rev_data[i][idx] + 0;
		if (old != 0 && old != big5)
		{
			if (uc == 0xFFFD)
			{
				rev_data[i][idx] = big5;
				return;
			}

			printf("duplicate reverse mapping for U+%04x: 0x%04x vs 0x%04x\n", uc, old, big5) > "/dev/stderr";
			bad = 1;
			return;
		}

		rev_data[i][idx] = big5;
		return;
	}
}

function dump_dense_array(kind, page, total)
{
	@local i, v;

	for (i = 0; i < total; i++)
	{
		if ((i % 9) == 0) printf("\t");

		if (kind == "forward")
			v = fwd_data[page][i] + 0;
		else
			v = rev_data[page][i] + 0;

		printf("0x%04x", v);
		if (i + 1 < total) printf(", ");

		if ((i % 9) == 8 || i + 1 >= total)
			printf("\n");
	}
}

function dump_forward_page(i)
{
	printf("/* page %d 0x%04x-0x%04x */\n", fwd_page_no[i], fwd_from[i], fwd_to[i]);
	printf("static const hawk_uint16_t %s[] = {\n", fwd_name[i]);
	dump_dense_array("forward", i, fwd_len[i]);
	printf("};\n");
}

function dump_reverse_page(i)
{
	printf("/* page %d 0x%04x-0x%04x */\n", rev_page_no[i], rev_from[i], rev_to[i]);
	printf("static const hawk_uint16_t %s[] = {\n", rev_name[i]);
	dump_dense_array("reverse", i, rev_len[i]);
	printf("};\n");
}